Ciclos For/Next

Los ciclos For/Next le permiten evaluar una secuencia de enunciados varias veces. Esto es diferente a los enunciados If y Select, donde el programa pasa por cada enunciado máximo una vez durante la evaluación de la fórmula. Los ciclos For/Next funcionan mejor cuando conoce de antemano la cantidad de veces que es necesario evaluar un enunciado.

Sintaxis del ciclo For mediante ejemplos

Ejemplo 1

Suponga que desea invertir la cadena {Cliente.Nombre del cliente}. Por ejemplo, la compañía "City Cyclists" pasa a ser "stsilcyC ytiC".

Rem Invertir una cadena, versión 1
formula = ""
Dim longitudCadena
longitudCadena = Len ({Cliente.Nombre del cliente})
Dim i
For i = 1 To longitudCadena
   Dim posGráfica
   posGráfica = longitudCadena - i + 1
   formula = formula & _
             Mid({Cliente.Nombre del cliente}, posGráfica, 1)
Next i

Examinemos cómo funciona esta fórmula suponiendo que el valor actual del campo {Cliente.Nombre del cliente}es "Clean Air". La variable longitudCadena se asigna a la longitud de "Clean Air", es decir, 9. En este momento también se escribe para que sea una variable numérica. La variable i se conoce como variable de contador ya que su valor cambia con cada iteración del ciclo For. Es decir, se usa para contar las iteraciones del ciclo. El ciclo For tendrá 9 iteraciones, durante la primera vez, i es 1, luego i es 2, luego i es 3 y así sucesivamente hasta que finalmente i = 9. Durante la primera iteración, el noveno carácter de {Cliente.Nombre del cliente} se anexa a la variable especial vacía formula. Como resultado la fórmula es igual a "r" después de la primera iteración. Durante la segunda iteración, el octavo carácter de {Cliente.Nombre del cliente}se anexa a la fórmula y de este modo la fórmula es igual a "ri". Esto continúa hasta después de la novena iteración, la fórmula es igual a "riA naelC", que es la cadena invertida.

Ejemplo 2

He aquí una versión más simple de la fórmula anterior, que usa una cláusula Step con un valor negativo de Step de -1. Para el ejemplo de "Clean Air", i es 9 para la primera iteración, 8 para la segunda, 7 para la tercera y así sucesivamente hasta que es 1 en la iteración final.

Rem Invertir una cadena, versión 2
formula = ""
Dim i
For i = Len ({Cliente.Nombre del cliente}) To 1 Step -1
   formula = formula + _
             Mid({Cliente.Nombre del cliente}, i, 1)
Next i
Ejemplo 3

La versión más simple es usar la función incorporada StrReverse:

Rem Invertir una cadena, versión 3
formula = StrReverse ({Cliente.Nombre del cliente})

Las funciones de cadena incorporada de Seagate Crystal Reports 8 pueden manejar muchas de las aplicaciones de procesamiento de cadenas que tradicionalmente serían manejadas usando un ciclo For/Next o algún otro tipo de ciclo. Sin embargo, los ciclos For/Next proporcionan la mayor flexibilidad y potencia en el procesamiento de cadenas y matrices. Esto puede ser vital si las funciones incorporadas no cubren la aplicación que le interesa.



Seagate Software, Inc.
http://www.seagatesoftware.com
Envíe sus comentarios a:
techpubs@seagatesoftware.com