Ciclos For

Los ciclos For le permiten evaluar una secuencia de expresiones varias veces. Esto es diferente a los enunciados If y Select, donde el programa pasa por cada expresión máximo una vez durante la evaluación de la fórmula. Los ciclos For funcionan mejor cuando conoce de antemano la cantidad de veces que es necesario evaluar una expresión.

Sintaxis del ciclo For mediante ejemplos

Ejemplo 1

Suponga que desea invertir la cadena {Cliente.Nombre del cliente}. Por ejemplo, la compañía "City Cyclists" pasa a ser "stsilcyC ytiC".

//Invertir una cadena, versión 1
Local StringVar cadena := "";
Local NumberVar longitudCadena := 
   Length ({Cliente.Nombre del cliente});
Local NumberVar i;
For i := 1 To longitudCadena Do

(

   Local NumberVar posGráfica := longitudCadena - i + 1;
   cadena := cadena + {Cliente.Nombre del 
cliente}[posGráfica]
);
cadena

Examine cómo funciona esta fórmula asumiendo que el valor actual del campo {Cliente.Nombre del cliente} es "Clean Air". La variable longitudCadena se asigna a la longitud de "Clean Air", es decir, 9. La variable i se conoce como variable de contador ya que su valor cambia con cada iteración del ciclo For. Es decir, se usa para contar las reiteraciones del ciclo. El ciclo For tendrá 9 iteraciones, durante la primera vez, i es 1, luego i es 2, luego i es 3 y así sucesivamente hasta que finalmente i = 9. Durante la primera iteración, el noveno carácter de {Cliente.Nombre del cliente} se anexa a la variable especial vacía cadena. Por eso cadena es igual a "r" después de la primera iteración. Durante la segunda iteración, el octavo carácter de {Cliente.Nombre del cliente}se anexa a cadena y de este modo cadena es igual a "ri". Esto continúa hasta después de la novena iteración, la cadena es igual a "riA naelC", que es la cadena invertida.

Ejemplo 2

Esta versión es más simple que la fórmula anterior, ya que usa una cláusula Step con un valor Step negativo de -1. Para el ejemplo de "Clean Air", i es 9 para la primera iteración, 8 para la segunda, 7 para la tercera y así sucesivamente hasta que es 1 en la iteración final.

//Invertir una cadena, versión 2
Local StringVar cadena := "";
Local NumberVar longitudCadena := 
   Length ({Cliente.Nombre del cliente});
Local NumberVar i;
For i := longitudCadena To 1 Step -1 Do
(
   cadena := cadena + {Cliente.Nombre del cliente}[i]
);
cadena
Ejemplo 3

La versión más simple es usar la función incorporada StrReverse:

//Invertir una cadena, versión 3
StrReverse ({Cliente.Nombre del cliente})

Las funciones de cadena incorporada de Seagate Crystal Reports 8 pueden manejar muchas de las aplicaciones de procesamiento de cadenas que tradicionalmente serían manejadas usando un ciclo For o algún otro tipo de ciclo. No obstante, los ciclos For proporcionan la mayor flexibilidad en el procesamiento de cadenas, así como capacidad en el procesamiento de matrices, que pueden ser esenciales si las funciones incorporadas no abarcan el programa que desea usar.



Seagate Software, Inc.
http://www.seagatesoftware.com
Envíe sus comentarios a:
techpubs@seagatesoftware.com