Más detalles sobre las expresiones If

La expresión If es una expresión. Es decir, evalúa un valor de un tipo dado. Si no hay cláusula Else y la condición no es verdadera, entonces el valor será el predeterminado para el tipo. Por ejemplo:

If Length ({Empleado.Nombre}) < 5 Then
   "corto"

La expresión If anterior devuelve un valor de cadena. El valor de cadena es "corto" si el nombre del empleado tiene menos de 5 letras y será la cadena vacía "" si no es así.

Considere la fórmula:

If Año({Pedidos.Fecha del pedido}) >= 1995 Then
   {Pedidos.Fecha del pedido}

Para las fechas de pedidos anteriores a 1995, la expresión If anterior devuelve el valor fechahora nulo. Es un valor de fechahora en lugar de un valor de fecha, dado que {Pedidos.Fecha del pedido} es un campo de fechahora de base de datos. Seagate Crystal Reports no imprime el valor nulo de fechahora, de modo que si se incluye la fórmula anterior en un informe, el campo de fórmula quedaría en blanco para las fechas de pedidos anteriores a 1995. Los valores nulos de hora y los valores nulos de fecha se comportan en forma similar.

Este ejemplo ilustra el uso de paréntesis para que se ejecute más de una expresión como resultado de una condición If. Una compañía de EE.UU. cobra una tarifa del 5 por ciento por pedidos enviados en un plazo de 3 días y un 2 por ciento cuando no es así. Desea imprimir mensajes como "El envío urgente cuesta $100,00" o "El envío estándar cuesta $20,00", según sea el caso.

Local StringVar mensaje;
Local CurrencyVar envío;
If {Pedidos.Fecha del envío} - {Pedidos.Fecha del pedido} 
<= 3 Then
(
   mensaje := "urgente";
   //Un punto y coma al final de la siguiente línea
   //es opcional
   envío := {Pedidos.Monto del pedido} * 0.05
) //Aquí no se puede poner un punto y coma
Else
(
   mensaje := "estándar";
   envío := {Pedidos.Monto del pedido} * 0.02;
);
//El punto y coma anterior es necesario para separar la 
//expresión If de la expresión final siguiente
"El envío " & mensaje & " cuesta " & CStr (enviar)

Cuando se agrupan expresiones con paréntesis, se considera todo el grupo como una sola expresión y su valor y tipo son el valor y tipo de la expresión final dentro del paréntesis.

//La expresión de grupo de paréntesis como un todo tiene
//tipo monetario
(
   //La primera expresión entre paréntesis tiene
   //tipo de cadena
   mensaje := "urgente";
   //La segunda y última expresión entre paréntesis
   //tiene tipo monetario
   envío := {Pedidos.Monto del pedido} * 0.05;
)

Por eso, por ejemplo, la siguiente fórmula da un error. La razón es que la parte Then de la expresión If devuelve un valor monetario mientras que la parte Else devuelve un valor de cadena. Esto no está permitido, dado que la expresión If es una expresión y, por lo tanto, siempre debe devolver un valor de un sólo tipo.

//Una fórmula errónea
Local StringVar mensaje;
Local CurrencyVar envío;
If {Pedidos.Fecha de envío} - {Pedidos.Fecha del pedido} 
<= 3 Then
(
   mensaje := "urgente";
   envío := {Pedidos.Monto del pedido} * 0.05
)
Else
(
   //Las 2 líneas siguientes se intercambiaron
   envío := {Pedidos.Monto del pedido} * 0.02;
   mensaje := "estándar";
);
"El envío " & mensaje & " cuesta " & CStr (enviar)

Una forma de corregir una fórmula errónea sin preocuparse del orden de la expresión es simplemente hacer que la expresión If devuelva un valor constante del mismo tipo en cada rama. Por ejemplo, la expresión If ahora devuelve el valor numérico 0:

//Fórmula errónea corregida
Local StringVar mensaje;
Local CurrencyVar envío;
If {Pedidos.Fecha de envío} - {Pedidos.Fecha del pedido} 
<= 3 Then
(
   mensaje := "urgente";
   envío := {Pedidos.Monto del pedido} * 0.05;
   0
)
Else
(
   envío := {Pedidos.Monto del pedido} * 0.02;
   mensaje := "estándar";
   0
);
"El envío " & mensaje & " cuesta " & CStr (enviar)


Seagate Software, Inc.
http://www.seagatesoftware.com
Envíe sus comentarios a:
techpubs@seagatesoftware.com