La expresión Select es similar a una expresión If. A veces, no obstante, es posible escribir fórmulas más claras y menos repetitivas usando la expresión Select. Por ejemplo, para evaluar el campo {Cliente.Fax} y determinar si el código postal es del Estado de Washington (WA) (206, 360, 509) o de Colombia Británica (BC), Canadá (604, 250):
//Ejemplo de expresión Select 1
Select {Cliente.Fax}[1 To 3]
Case "604", "250" :
"BC"
Case "206", "509", "360" :
"WA"
Default :
"";
La expresión que sigue a la palabra clave Select se denomina condición de selección. En el ejemplo anterior es {Cliente.Fax}[1 To 3]. La expresión Select intenta buscar el primer caso (Case) que coincida con la condición de selección y luego ejecuta la expresión que sigue a los dos punto para ese caso. El caso predeterminado coincide si ninguno de los casos precedentes coincide con la condición Select. Observe que también hay dos puntos después del valor predeterminado.
//Ejemplo de mismo efecto que Select 1
Local StringVar cPostal := {Cliente.Fax}[1 To 3];
If cPostal In ["604", "250"] Then
"BC"
Else If cPostal In ["206", "509", "360"] Then
"WA"
Else
"";
Esta fórmula agrupa el número de nominaciones al Oscar recibidas por una película en categorías baja, media, alta o extrema y, en el proceso, muestra las posibilidades de que la expresión liste las siguientes etiquetas de caso (Case):
//Ejemplo de expresión Select 2
Select {película.NOM}
Case 1,2,3, Is < 1 :
(
//Es posible tener listas de expresiones usando
//paréntesis
10 + 20;
"baja"
)
Case 4 To 6, 7, 8, 9 :
"media"
Case 10 :
"alta"
Default :
"extrema"
La cláusula de valor predeterminado (Default) de la expresión Select es opcional. Si falta la cláusula de valor predeterminado y ninguno de los casos coincide, entonces la expresión Select devuelve el valor predeterminado para su tipo de expresión. Por ejemplo, si en el ejemplo anterior se omitiese la cláusula predeterminada y {película.NOM} = 11, devolvería la cadena vacía "". La expresión Select es una expresión, así que se le aplican los mismos comentarios que se explican en la sección Más detalles sobre las expresiones If.
| Seagate Software, Inc. http://www.seagatesoftware.com Envíe sus comentarios a: techpubs@seagatesoftware.com |