Ejemplo If

Supongamos que una compañía desea calcular el estimado del importe de impuestos que los empleados han de pagar y escribir además un mensaje apropiado. Los ingresos inferiores a $8.000 no están sujetos a impuestos; los ingresos entre $8.000 y $20.000 lo están al 20%; los ingresos entre $20.000 y $35.000 están sujetos al 29%; y los ingresos superiores a $35.000 lo están al 40%.

//Ejemplo de expresión If 5
Local CurrencyVar impuestos := 0;
Local CurrencyVar ingresos := {Empleado.Salario};
Local StringVar mensaje := "";
If ingresos < 8000 Then
(
   mensaje := "no";
   impuestos := 0
)
Else If ingresos >= 8000 And ingresos < 20000 Then
(
   mensaje := "la más baja";
   impuestos := (ingresos - 8000)*0.20
)
Else If ingresos >= 20000 And ingresos < 35000 Then
(
   mensaje := "la intermedia";
   impuestos := (20000 - 8000)*0.20 + (ingresos - 
20000)*0.29
)
Else
(
   mensaje := "la más alta";
   impuestos := (20000 - 8000)*0.20 + (35000 - 
20000)*0.29 +
          (ingresos - 35000)*0.40
);
//Usar 2 decimales y el punto como
//separador de miles
Local StringVar cadenaImpuestos := CStr (impuestos, 2, ".");
"Usted está en " & mensaje & " cuota impositiva. " &
"Sus impuestos estimados son " & cadenaImpuestos & "."

Nota:    El uso de variables simplifica la lógica del cálculo. Además, hay 2 expresiones que se ejecutan cuando se cumple una de las condiciones; una asigna la variable impuestos y la otra asigna la variable mensaje. A menudo es útil que se ejecuten expresiones múltiples como resultado de una condición.



Seagate Software, Inc.
http://www.seagatesoftware.com
Envíe sus comentarios a:
techpubs@seagatesoftware.com